Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00023_NavStructMgr.ls

Text File | 2004-07-11 | 3.3 KB | 179 lines

--
-- NavStructMgr
--
-- handles the basic navigation for an application.
-- major calls are:
--   next
--   prev
--   goLevel [levelNumber]


-- constants:

property ancestor

property appPath
property mainMovie

property navStruct

property level
property activity

property returnFrame


on new me
  set ancestor = new (script "Banner")

  set level = 0
  set activity = 0
  set returnFrame = 1

  set appPath = the pathname   -- possibly something else...
  set mainMovie = the movieName
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


on getLevel me
  if not stringP (level) then return 0
  else return integer (char 7 to 8 of level)
end


on setStruct me, lst
  if ilk (lst, #proplist) then
    -- makeField (me, "NavStruct", lst)
    set navStruct = lst
  end if
end


on goMain me
  if the movieName = mainMovie then return
  cleanUp (me)
  updateStage
  go to frame returnFrame of movie appPath & mainMovie
  unloadCast (me)
end


-- go to a lesson in a particular application (as laid out in the file structure):
-- pass an integer to represent the level number
-- and r (the frame to return to in the main movie)

on goLevel me, num, r
  -- check for legal return frames:
  if stringP (r) then set r = label(r)
  if integerP (r) and r > 0 then set returnFrame = r
  else set r = 1
  cursor 4
  if getPropAt (navStruct, num) > 0 then
    set level = getPropAt (navStruct, num)  -- level number
    set lst = getAProp (navStruct, level)
    set activity = getAt (lst, 1)
    goActivity (me)
  else
    go Frame r
  end if
  --JCODE setPrintString (me, the text of member ("printString,"&level) of castLib "UI.cst")
  setPrintBackground (me, ("A-CERT-"&level&".p"))
  setPrintForgroundMem (me, "certificateName")

  cursor -1
end


-- go to the currently chosen activity,
-- level and activity must be marked before this call is made.

on goActivity me
  -- do nothing if:
  if (not stringP (level)) or (not stringP (activity)) then return
  cleanUp (me)
  go to movie (appPath & "modules" & pathChar (me) & level & pathChar (me) & activity)
  unloadCast (me)
  cursor 200
end


on isLastActivity me
  set lst = getAProp (navStruct, level)
  set curr = getPos (lst, activity)

  set curr = curr + 1
  if curr <= count (lst) then return 0
  else
    return 1
  end if
end


-- is this activity self contained?

on isSelfContained me
  if not stringP (activity) then return 1
  else return 0
end


-- go to the next activity in the current level directory.
-- if there is no next activity then return to the main movie.

on next me
  if not stringP (activity) then
    alert "This activity is self contained."
    exit
  end if

  set lst = getAProp (navStruct, level)
  set curr = getPos (lst, activity)

  set curr = curr + 1
  if curr <= count (lst) then
    set activity = getAt (lst, curr)
    goActivity (me)
  else
    goMain (me)
  end if
end


-- go to the previous activity in the current level directory.
-- if there is no previous activity then return to the main movie.

on prev me
  set lst = getAProp (navStruct, level)
  set curr = getPos (lst, activity)

  set curr = curr - 1
  if curr > 0 then
    set activity = getAt (lst, curr)
    goActivity (me)
  else
    goMain (me)
  end if
end


on cleanUp me
  spritesOff (me)
  killActorList (me)
  unloadCast (me)
end



on updateCurrentModule me
  set mn = the movieName
end